#! /bin/csh -f

# GMT3.3.5 に檜垣さん作の patch
#
#    GMT3.3.5-j.patch
#
# をあてると日本語フォントと英字フォントを混在させることができます。
#
#   詳しい情報は
# 
#     http://plaza26.mbn.or.jp/~higamasa/gmt/
# 
# にあります。作者の下田さん、檜垣さんに感謝いたします。
#
# これを使って、観測点の図を描いてみましょう。
#
#                                                     00/09/01 筧

# 日本語フォント・英字フォントを混在で使います
setenv GMTCHARSET ja_JP.EUC

# ヘッダのフォントは明朝 + Times Roman（font No. 4）の混在にする。
# ↓これは
#     gmtset HEADER_FONT 104
# としても同じ。
# font No. 101- 134 で日本語・英字混合の文字を書かせると、
# 英字のフォントは下2桁の font No. のフォントに、
# 日本語のフォントはリュウミンライトになります
gmtset HEADER_FONT Mincho-Times-Roman

# ヘッダのフォントサイズは 24 point
gmtset HEADER_FONT_SIZE 24

# スケールバーのフォントサイズは 14 point
gmtset LABEL_FONT_SIZE  14

# 出力PSファイルの名前をshell変数 output に入れる
set output  = station_ja.ps

# 観測点名とその座標、名前を書く位置を並べたファイルの名前を
# shell変数 station に入れる
set station = station.txt

# 座標枠を描く。ヘッダは"GPS観測点"
psbasemap -JM14 -R135.1/135.45/34.6/34.85 \
  -Ba0.1f0.05:."GPS観測点":WenS \
  -X4 -Y12 -P -K >! $output

# 海岸線を描き、陸に色をつけ、スケールバーを描く
pscoast -JM -R -Df -G150/200/150 -S230/230/255 -W1 \
  -Lf135.2/34.63/34.5/10 -P -K -O >> $output

# 観測点の位置に▲を描く
awk '{print $2, $3}' $station | \
psxy -JM -St0.4 -G255/100/100 -W3 -R -P -K -O >> $output

# 観測点名を▲のちょっと（0.01°）上に書く。
# 英字フォントは Helvetica-Bold (font No. 1)
# font No. 1- 34 で日本語・英字混合の文字を書かせると、
# 日本語のフォントはゴシックBBBになります。
awk '{print $2, $3+0.01, 14, 0, 1, $4, $1}' $station | \
pstext -JM -R -P -O -K >> $output

# 観測点名を▲のちょっと（0.01°）下に書く。
# 英字フォントは Helvetica-Bold (font No. 1)
# font No. 101- 134 で日本語・英字混合の文字を書かせると、
# 英字のフォントは下2桁の font No. のフォントに、
# 日本語のフォントはリュウミンライトになります
awk '{print $2, $3-0.01, 14, 0, 101, $4, $1}' $station | \
pstext -JM -R -P -O >> $output

# station.txt の中身は以下の通りです
# 神戸大GPS  135.23490001    34.72574519   CM
# 芦屋GPS    135.29149674    34.77318152   LM
# 有馬GPS    135.24831107    34.80123688   RM